AtomNeb – Library for Atomic Data of Ionized Nebulae

AtomNeb is an atomic database useful for nebular spectral analysis, plasma diagnostics, and abundance analysis.

• AtomNeb includes energy levels (Ej), collision strengths (Ωij), and transition probabilities (Aij) of the most ions commonly observed in ionized nebulae. AtomNeb uses the Flexible Image Transport System (FITS) format to store atomic data.
• AtomNebi includes effective recombination coefficient (αeff) of recombination lines of Ions typically observed in ionized nebulae, as well as Branching ratios (Br).

AtomNeb requires the Interactive Data Language (IDL) compiler developed by ITT Exelis Visual Information Solutions (ITT Exelis VIS).

Collisionally Excitation Atomic Data

• Collection from the NIST and CHIANTI atomic database, and some improvements from Cloudy and pyNeb.
• Chianti52 from the CHIANTI atomic database version 5.2.
• Chianti60 from the CHIANTI atomic database version 6.0.
• Chianti70 from the CHIANTI atomic database version 7.0.

Recombination Atomic Data

• Recombination data for C II (Davey et al. 2000), N II (Escalante and Victor 1990), O II (Storey 1994; Liu et al. 1995), and Ne II ions (Kisielius et al. 1998), including Branching ratios (Br) for O II and N II ions.
• Hydrogenic ions for Z=1 to 8, namely H I, He II, Li III, Be IV, B V, C VI, N VII, and O VIII ions from Storey and Hummer (1995).
• Recombination data for H, He, C, N, O, Ne ions from Pequignot, Petitjean and Boisson (1991).
• He I recombination data from Porter et al (2012) and (2013).
• N II recombination data from Fang, Storey and Liu (2011) and (2013).

Usage

Collisionally Excitation Atomic Data

Atom_Elj_file='/home/atomic_data/atomneb/atomic-data/chianti70/AtomElj.fits'
Atom_Omij_file='/home/atomic_data/atomneb/atomic-data/chianti70/AtomOmij.fits'
Atom_Aij_file='/home/atomic_data/atomneb/atomic-data/chianti70/AtomAij.fits'

; read Energy Levels (Ej) list
elj_data_list=atomneb_read_elj_list(Atom_Elj_file)
; read Collision Strengths (Omegaij) list
omij_data_list=atomneb_read_omij_list(Atom_Omij_file)
; read Transition Probabilities (Aij) list
aij_data_list=atomneb_read_aij_list(Atom_Aij_file)

; read Energy Levels (Ej) references
elj_data_reference=atomneb_read_elj_references(Atom_Elj_file)
; read Collision Strengths (Omegaij) references
omij_data_reference=atomneb_read_omij_references(Atom_Omij_file)
; read Transition Probabilities (Aij) references
aij_data_reference=atomneb_read_aij_references(Atom_Aij_file)

atom='o'
ion='iii'
; read Energy Levels (Ej) of O III upto level number 6
oiii_elj_data=atomneb_read_elj(Atom_Elj_file, atom, ion, level_num=6)
; print Levels of O III
print,oiii_elj_data.J_v
; print Energy Levels (cm-1) of O III
print,oiii_elj_data.Ej

; get citations for Energy Levels (Ej) Reference o_iii_elj
citation=atomneb_get_elj_reference_citation(Atom_Elj_file, 'o_iii_elj')
; print citations for Energy Levels (Ej) Reference o_iii_elj
print,citation

atom='o'
ion='iii'
; read Collision Strengths (Omegaij) of O III
oiii_omij_data=atomneb_read_omij(Atom_Omij_file, atom, ion)
; print Level 1 of Collision Strengths (Omegaij) of O III
print,oiii_omij_data.level1
; print Level 2 of Collision Strengths (Omegaij) of O III
print,oiii_omij_data.level2
; print Strength[1] of Collision Strengths (Omegaij) of O III
print,oiii_omij_data[0].strength

atom='o'
ion='iii'
; list all Collision Strengths (Omegaij) data for O III
list_oiii_omij_data=atomneb_search_omij(Atom_Omij_file, atom, ion)
; print all Collision Strengths (Omegaij) of O III
print,list_oiii_omij_data

atom='o'
ion='iii'
; list all Collision Strengths (Omegaij) references for O III
list_oiii_omij_reference=atomneb_list_omij_references(Atom_Omij_file, atom, ion)
; print all Collision Strengths (Omegaij) References for O III
print,list_oiii_omij_reference

atom='o'
ion='iii'
reference='CHI70'
; get citations for Collision Strengths (Omegaij) of O III with reference CHI70
citation=atomneb_get_omij_reference_citation(Atom_Omij_file, atom, ion, reference)
; print citations for Collision Strengths (Omegaij) of O III with reference CHI70
print,citation

atom='o'
ion='iii'
reference='CHI70'
; read Transition Probabilities (Aij) of O III with reference CHI52
oiii_aij_data=atomneb_read_aij(Atom_Aij_file, atom, ion)
; print Transition Probabilities (Aij) of O III with reference CHI52
print,oiii_aij_data.Aij[*,*]

atom='o'
ion='iii'
reference='CHI70'
; get citations for Transition Probabilities (Aij) of O III with reference CHI70
citation=atomneb_get_aij_reference_citation(Atom_Aij_file, atom, ion, reference)
; print citations for Transition Probabilities (Aij) of O III with reference CHI70
print,citation

atom='o'
ion='iii'
; list all Transition Probabilities (Aij) data for O III
list_oiii_aij_data=atomneb_search_aij(Atom_Aij_file, atom, ion)
; print all Transition Probabilities (Aij) data for O III
print,list_oiii_aij_data

atom='o'
ion='iii'
; list all Transition Probabilities (Aij) references for O III
list_oiii_aij_reference=atomneb_list_aij_references(Atom_Aij_file, atom, ion)
; print all Transition Probabilities (Aij) references for O III
print,list_oiii_aij_reference

Recombination Atomic Data
Atom_RC_file='/home/atomic_data/atomneb/atomic-data-rc/rc_collection.fits'

atom='c'
ion='iii' ; C II
; read Recombination Coefficients (Aeff) of C II
cii_rc_data=atomneb_read_aeff_collection(Atom_RC_file, atom, ion)
temp=size(cii_rc_data.Wavelength,/DIMENSIONS)
n_line=temp[0]
; print information needed for Recombination Coefficients (Aeff) of C II
for i=0,n_line-1 do print,cii_rc_data[i].Wavelength, cii_rc_data[i].a, $
cii_rc_data[i].b, cii_rc_data[i].c, $
cii_rc_data[i].d, cii_rc_data[i].f

atom='n'
ion='iii' ; N II
; read Recombination Coefficients (Aeff) of N II
nii_rc_data=atomneb_read_aeff_collection(Atom_RC_file, atom, ion)
nii_rc_data_br=atomneb_read_aeff_collection(Atom_RC_file, atom, ion, /br)
temp=size(nii_rc_data.a,/DIMENSIONS)
n_line=temp[0]
; print information needed for Recombination Coefficients (Aeff) of N II
for i=0,n_line-1 do print,nii_rc_data[i].a, nii_rc_data[i].b,  nii_rc_data[i].c
temp=size(nii_rc_data_br.Wavelength,/DIMENSIONS)
n_line=temp[0]
; print forBranching ratios (Br) of N II
for i=0,n_line-1 do print,nii_rc_data_br[i].Wavelength, nii_rc_data_br[i].br, $
nii_rc_data_br[i].g1,nii_rc_data_br[i].g2, $
nii_rc_data_br[i].Mult1, $
nii_rc_data_br[i].LowerTerm,nii_rc_data_br[i].UpperTerm

atom='o'
ion='iii' ; O II
; read Recombination Coefficients (Aeff) of O II
oii_rc_data=atomneb_read_aeff_collection(Atom_RC_file, atom, ion)
oii_rc_data_br=atomneb_read_aeff_collection(Atom_RC_file, atom, ion, /br)
temp=size(oii_rc_data.a2,/DIMENSIONS)
n_line=temp[0]
; print information needed for Recombination Coefficients (Aeff) of O II
for i=0,n_line-1 do print,oii_rc_data[i].Term,oii_rc_data[i].Case1, $
oii_rc_data[i].a2,oii_rc_data[i].a4,oii_rc_data[i].a5,oii_rc_data[i].a6, $
oii_rc_data[i].b,oii_rc_data[i].c,oii_rc_data[i].d
temp=size(oii_rc_data_br.Wavelength,/DIMENSIONS)
n_line=temp[0]
; print forBranching ratios (Br) of O II
for i=0,n_line-1 do print,oii_rc_data_br[i].Wavelength, $
oii_rc_data_br[i].Br_A,oii_rc_data_br[i].Br_B,oii_rc_data_br[i].Br_C, $
oii_rc_data_br[i].g1,oii_rc_data_br[i].g2, $
oii_rc_data_br[i].Mult1,oii_rc_data_br[i].LowerTerm,oii_rc_data_br[i].UpperTerm

atom='ne'
ion='iii' ; Ne II
; read Recombination Coefficients (Aeff) of Ne II
neii_rc_data=atomneb_read_aeff_collection(Atom_RC_file, atom, ion)
temp=size(neii_rc_data.Wavelength,/DIMENSIONS)
n_line=temp[0]
; print information needed for Recombination Coefficients (Aeff) of Ne II
for i=0,n_line-1 do print,neii_rc_data[i].Wavelength, neii_rc_data[i].a, $
neii_rc_data[i].b, neii_rc_data[i].c, $
neii_rc_data[i].d, neii_rc_data[i].f, neii_rc_data[i].br

atom='c'
ion='iii' ; C III
; list all Recombination Coefficients (Aeff) data for C III
list_cii_aeff_data=atomneb_search_aeff_collection(Atom_RC_file, atom, ion)
; print all Recombination Coefficients (Aeff) of C III
print,list_cii_aeff_data

atom='c'
ion='iii' ; C III
; list all Recombination Coefficients (Aeff) references for C III
list_cii_aeff_reference=atomneb_list_aeff_collection_references(Atom_RC_file, atom, ion)
; print all Recombination Coefficients (Aeff) References for C III
print,list_cii_aeff_reference

atom='c'
ion='iii' ; C III
; get citations for Recombination Coefficients (Aeff) of C III with reference SSB14
citation=atomneb_get_aeff_collection_reference_citation(Atom_RC_file, atom, ion)
; print citations for Recombination Coefficients (Aeff) of C III with reference SSB14
print,citation

He I Recombination Atomic Data
Atom_RC_file='/home/atomic_data/atomneb/atomic-data-rc/rc_he_ii_PFSD12.fits'

atom='he'
ion='ii' ; He I
; read Recombination Coefficients (Aeff) of He I
hei_rc_data=atomneb_read_aeff_he_i_pfsd12(Atom_RC_file, atom, ion)
hei_rc_data_wave=atomneb_read_aeff_he_i_pfsd12(Atom_RC_file, atom, ion, /wavelength)
; print information needed for Recombination Coefficients (Aeff) of He I
print,hei_rc_data[0].Aeff
temp=size(hei_rc_data_wave.Wavelength,/DIMENSIONS)
n_line=temp[0]
for i=0,n_line-1 do print,hei_rc_data_wave[i].Wavelength, hei_rc_data_wave[i].LowerTerm, hei_rc_data_wave[i].UpperTerm

atom='he'
ion='ii' ; He I
; list all Recombination Coefficients (Aeff) data for He I
list_hei_aeff_data=atomneb_search_aeff_he_i_pfsd12(Atom_RC_file, atom, ion)
; print all Recombination Coefficients (Aeff) of He I
print,list_hei_aeff_data

atom='he'
ion='ii' ; He I
; list all Recombination Coefficients (Aeff) references for He I
list_hei_aeff_reference=atomneb_list_aeff_he_i_pfsd12_references(Atom_RC_file, atom, ion)
; print all Recombination Coefficients (Aeff) References for He I
print,list_hei_aeff_reference

atom='he'
ion='ii' ; He I
reference='PFSD13'
; get citations for Recombination Coefficients (Aeff) of He I
citation=atomneb_get_aeff_he_i_pfsd12_reference_citation(Atom_RC_file, atom, ion, reference=reference)
; print citations for Recombination Coefficients (Aeff) of He I
print,citation

Acknowledgement
A. Danehkar (2018) PASA 35:e005